PKGBUILD

# Maintainer: Sébastien Luttringer

pkgname=archrepo-git
pkgver=1
pkgrel=1
pkgdesc='Seblu Arch Linux Repositories Tools'
arch=('any')
url='https://git.seblu.net/archlinux/archrepo'
license=('GPL2')
makedepends=('git')
depends=('bash' 'devtools' 'hardlink')

pkgver() {
  cd "$startdir"
  printf '%s.%(%y%m%d%H%M)T' "$(git rev-list --count HEAD)"
}

package() {
  cd "$startdir"
  # install legal stuff
  install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
  install -m644 COPYRIGHT LICENSE "$pkgdir/usr/share/licenses/$pkgname"
  # install config
  d="$pkgdir"/usr/share/devtools/pacman.conf.d
  install -dm755 "$d"
  install -m644 pacman-seblu.conf "$d"/seblu.conf
  install -m644 pacman-multilib-seblu.conf "$d"/multilib-seblu.conf
  # install binaries
  install -dm755 "$pkgdir"/usr/bin
  install -m755 seblu-commit seblu-remove seblu-cleanup seblu-push \
    "$pkgdir"/usr/bin
  # symlink archbuild
  ln -s archbuild "$pkgdir/usr/bin/seblu-x86_64-build"
  ln -s archbuild "$pkgdir/usr/bin/multilib-seblu-build"
  # add sudo config
  install -dm750 "$pkgdir/etc/sudoers.d"
  install -m644 sudoers "$pkgdir/etc/sudoers.d/50-devtools-seblu"
}

# vim:set ts=2 sw=2 et: