#!/bin/zsh

# Copyright © Sébastien Luttringer
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.

# kexec for dummies

BOOT_DIR="${BOOT_DIR:-/boot}"

(( UID > 0 )) && { echo "You must be root" >&2; exit 1; }
whence -p kexec >/dev/null || { echo "kexec is not in PATH" >&2; exit 1; }
[[ -r "$BOOT_DIR" ]] || { echo "Unable to read $BOOT_DIR" >&2; exit 1; }

read machineid < /etc/machine-id

kernels=( "$BOOT_DIR"/vmlinuz*(Nom) "$BOOT_DIR/$machineid"/*/linux(Nom) )
(( ${#kernels[@]} > 0 )) || { echo "No kernel found." >&2; exit 2; }

select kernel in "${kernels[@]}"; do
	if [[ -e "${kernel%/linux*}/initrd" ]]; then
		initrd="--initrd=${kernel%/linux*}/initrd"
	elif [[ -e "${kernel%/vmlinuz*}/initramfs${kernel##*/vmlinuz}.img" ]]; then
		initrd="--initrd=/boot/initramfs-${kernel#*-}.img"
	else
		echo 'No initrd detected. Press a key to continue?'
		read key
	fi
	if ! kexec -l --reuse-cmdline "$initrd" "$kernel"; then
		printf '\e[1;31mUnable to load kernel/initrd\e[0m\n' >&2
		exit 42
	fi
	systemctl kexec
	break
done