Remove mc-git

# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>

# Contributor: Tsekhovoy Eugene aka Krash <8552246@gmail.com>

pkgname=mc-git

pkgver=20120125

pkgrel=1

pkgdesc='GNU Midnight Commander is a s-lang based file manager'

url='https://midnight-commander.org/'

arch=('i686' 'x86_64')

license=('GPL')

depends=('glib2' 'slang' 'perl')

makedepends=('git' 'cvs')

conflicts=('mc' 'mc-cvs' 'mc-fork-svn' 'mc-mp' 'mc-slavz' 'mc-suse')

provides=('mc')

_gitroot='https://github.com/MidnightCommander/mc.git'

_gitname='mc'

build() {

  if [[ -d $_gitname ]]; then

    cd $_gitname

    git clean -qfd

    git pull -v origin

  else

    git clone -v $_gitroot

    cd $_gitname

  fi

  # http://git.yoctoproject.org/cgit.cgi/poky-contrib/commit/?h=dcui/mc&id=338da10abcd744ab75dfb184f8f81370727e5653

  sed -i 's/pkglibexec_SCRIPTS = $(SCRIPTS_OUT)/pkgdata_SCRIPTS = $(SCRIPTS_OUT)/g' contrib/Makefile.am

  ./autogen.sh

  export MCREVISION=$(git describe --tags)

  ./configure                     \

      --prefix=/usr               \

      --sysconfdir=/etc           \

      --libexecdir=/usr/lib       \

      --enable-background         \

      --enable-network            \

      --enable-netcode            \

      --enable-charset            \

      --enable-nls                \

      --with-vfs                  \

      --with-edit                 \

      --with-screen=slang         \

      --without-x                 \

      --without-samba             \

      --without-gpm-mouse         \

      --without-gnome             \

      --without-debug             \

      --without-included-gettext  \

      --disable-dependency-tracking

  make

}

package() {

    cd $_gitname

    make DESTDIR="$pkgdir" install

}

# vim:set ts=2 sw=2 ft=sh et: