Add nginx-extra

# $Id: PKGBUILD 96471 2013-08-30 10:03:50Z seblu $

# Maintainer: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>

# Maintainer: Sébastien Luttringer

# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>

# Contributor: Miroslaw Szot <mss@czlug.icis.pcz.pl>

pkgname=nginx-extra

pkgver=1.5.4

pkgrel=1

pkgdesc='Lightweight HTTP server and IMAP/POP3 proxy server with extra modules'

arch=('i686' 'x86_64')

url='http://nginx.org'

license=('custom')

conflicts=('nginx')

provides=("nginx=$pkgver")

depends=('pcre' 'zlib' 'openssl')

backup=('etc/nginx/fastcgi.conf'

        'etc/nginx/fastcgi_params'

        'etc/nginx/koi-win'

        'etc/nginx/koi-utf'

        'etc/nginx/mime.types'

        'etc/nginx/nginx.conf'

        'etc/nginx/scgi_params'

        'etc/nginx/uwsgi_params'

        'etc/nginx/win-utf'

        'etc/logrotate.d/nginx')

source=("http://nginx.org/download/nginx-$pkgver.tar.gz"

        'http://web.iti.upv.es/~sto/nginx/ngx_http_auth_pam_module-1.2.tar.gz'

        'service'

        'logrotate')

sha256sums=('ad21d7ee5146d5c571917574b8a8bbab658faff6ffbff7cab2e69a3afadd65dc'

            '5a85970ba61a99f55a26d2536a11d512b39bbd622f5737d25a9a8c10db81efa9'

            '05fdc0c0483410944b988d7f4beabb00bec4a44a41bd13ebc9b78585da7d3f9b'

            '272907d3213d69dac3bd6024d6d150caa23cb67d4f121e4171f34ba5581f9e98')

build() {

    cd nginx-$pkgver

    ./configure \

        --prefix=/etc/nginx \

        --conf-path=/etc/nginx/nginx.conf \

        --sbin-path=/usr/bin/nginx \

        --pid-path=/run/nginx.pid \

        --lock-path=/run/lock/nginx.lock \

        --user=http \

        --group=http \

        --http-log-path=/var/log/nginx/access.log \

        --error-log-path=/var/log/nginx/error.log \

        --http-client-body-temp-path=/var/lib/nginx/client-body \

        --http-proxy-temp-path=/var/lib/nginx/proxy \

        --http-fastcgi-temp-path=/var/lib/nginx/fastcgi \

        --http-scgi-temp-path=/var/lib/nginx/scgi \

        --http-uwsgi-temp-path=/var/lib/nginx/uwsgi \

        --with-imap \

        --with-imap_ssl_module \

        --with-ipv6 \

        --with-pcre-jit \

        --with-file-aio \

        --with-http_dav_module \

        --with-http_gunzip_module \

        --with-http_gzip_static_module \

        --with-http_realip_module \

        --with-http_spdy_module \

        --with-http_ssl_module \

        --with-http_stub_status_module \

        --with-http_addition_module \

        --with-http_degradation_module \

        --with-http_flv_module \

        --with-http_mp4_module \

        --with-http_secure_link_module \

        --with-http_sub_module \

        --add-module=../ngx_http_auth_pam_module-1.2

    make

}

package() {

    cd nginx-$pkgver

    make DESTDIR="$pkgdir" install

    sed -e 's|\<user\s\+\w\+;|user html;|g' \

        -e '44s|html|/usr/share/nginx/html|' \

        -e '54s|html|/usr/share/nginx/html|' \

        -i "$pkgdir"/etc/nginx/nginx.conf

    rm "$pkgdir"/etc/nginx/*.default

    install -d "$pkgdir"/var/lib/nginx

    install -dm700 "$pkgdir"/var/lib/nginx/proxy

    chmod 750 "$pkgdir"/var/log/nginx

    chown http:log "$pkgdir"/var/log/nginx

    install -d "$pkgdir"/usr/share/nginx

    mv "$pkgdir"/etc/nginx/html/ "$pkgdir"/usr/share/nginx

    install -Dm644 "$srcdir"/logrotate "$pkgdir"/etc/logrotate.d/nginx

    install -Dm644 "$srcdir"/service "$pkgdir"/usr/lib/systemd/system/nginx.service

    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE

    rmdir "$pkgdir/run"

}

# vim:set ts=4 sw=4 et:

/var/log/nginx/*log {

	missingok

	create 640 http log

	sharedscripts

	compress

	postrotate

		test ! -r /var/run/nginx.pid || kill -USR1 `cat /var/run/nginx.pid`

	endscript

}

[Unit]

Description=A high performance web server and a reverse proxy server

After=syslog.target network.target

[Service]

Type=forking

PIDFile=/run/nginx.pid

ExecStartPre=/usr/bin/nginx -t -q -g 'pid /run/nginx.pid; daemon on; master_process on;'

ExecStart=/usr/bin/nginx -g 'pid /run/nginx.pid; daemon on; master_process on;'

ExecReload=/usr/bin/nginx -g 'pid /run/nginx.pid; daemon on; master_process on;' -s reload

ExecStop=/usr/bin/nginx -g 'pid /run/nginx.pid;' -s quit

[Install]

WantedBy=multi-user.target