Add opensmtpd

# $Id$

# Maintainer: Sébastien Luttringer

pkgname=opensmtpd

pkgver=5.3p1

pkgrel=0.1

pkgdesc='Free implementation of the server-side SMTP protocol'

arch=('i686' 'x86_64')

url='http://www.opensmtpd.org/'

license=('custom')

depends=('libevent')

provides=('smtp-server' 'smtp-forwarder')

conflicts=('smtp-server' 'smtp-forwarder')

backup=('etc/smtpd.conf' 'etc/aliases')

install=opensmtpd.install

source=("http://www.opensmtpd.org/archives/$pkgname-$pkgver.tar.gz"

        'smtpd.service'

        'smtpd.socket')

md5sums=('e98dfbfa17be1ff8f1e091319dfca4d8'

         '711f0c163a34b72249d38a9de0eb7320'

         'c2c01e9ca78df3f65efe40a7c0e17ee0')

build() {

  cd $pkgname-$pkgver

  ./bootstrap

  ./configure \

    --prefix=/usr \

    --sysconfdir=/etc \

    --sbindir=/usr/bin \

    --libexecdir=/usr/bin \

    --with-maildir=/var/spool/mail \

    --with-privsep-path=/var/empty \

    --with-sock-dir=/run \

    --with-privsep-user=mail \

    --with-filter-user=mail \

    --with-queue-user=mail \

    --with-pam

  make

}

package() {

  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir/" install

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  cd "$pkgdir/usr"

  # license

  install -Dm644 "$srcdir/smtpd.service" lib/systemd/system/smtpd.service

  install -Dm644 "$srcdir/smtpd.socket" lib/systemd/system/smtpd.socket

  # remove duplicate hardlink into a subfolder

  rm -r bin/opensmtpd

  # empty aliases file

  install -Dm644 /dev/null "$pkgdir/etc/aliases"

}

# vim:set ts=2 sw=2 et:

# arg 1:  the new package version

# arg 2:  the old package version

# arg 1:  the new package version

post_install() {

  makemap -t aliases /etc/aliases

}

# arg 1:  the old package version

post_remove() {

 rm -f /etc/aliases.db

}

# vim:set ts=2 sw=2 et:

[Unit]

Description=OpenSMTPD

After=network.target

[Service]

ExecStart=/usr/sbin/smtpd -d

[Install]

WantedBy=multi-user.target

[Unit]

Description=OpenSMTPD Socket

[Socket]

ListenStream=/run/smtpd.sock

[Install]

WantedBy=sockets.target