Add docker-io

# $Id$

# Maintainer: Sébastien "Seblu" Luttringer

pkgname=docker

pkgver=0.7.0

pkgrel=1

epoch=1

pkgdesc='Pack, ship and run any application as a lightweight container'

arch=('x86_64' 'i686')

url='http://www.docker.io/'

license=('Apache')

depends=('bridge-utils' 'iproute2' 'device-mapper' 'lxc' 'sqlite' 'systemd')

makdepends=('git' 'go')

source=("git+https://github.com/dotcloud/docker.git#tag=v$pkgver"

        'docker.service')

md5sums=('SKIP'

         'bba5868c45f45e4ae0dc9175e9e3017e')

# magic harcoded path

_magic=src/github.com/dotcloud

prepare() {

  mkdir -p "$_magic"

  ln -sfn "../../../docker" "$_magic/docker"

}

build() {

  cd "$_magic/docker"

  export GOPATH="$srcdir:$srcdir/$magic/docker/vendor"

  ./hack/make.sh dynbinary

}

package() {

  cd "$_magic/docker"

  install -Dm755 "bundles/$pkgver/dynbinary/docker-$pkgver" "$pkgdir/usr/bin/docker"

  install -Dm755 "bundles/$pkgver/dynbinary/dockerinit-$pkgver" "$pkgdir/usr/libexec/docker/dockerinit"

  # completion

  install -Dm644 "contrib/completion/bash/docker" "$pkgdir/usr/share/bash-completion/completions/docker"

  install -Dm644 "contrib/completion/zsh/_docker" "$pkgdir/usr/share/zsh/site-functions/_docker"

  # systemd

  install -Dm644 "$srcdir/docker.service" "$pkgdir/usr/lib/systemd/system/docker.service"

}

# vim:set ts=2 sw=2 et:

[Unit]

Description=Docker Daemon

After=network.target

[Service]

ExecStart=/usr/bin/docker -d

[Install]

WantedBy=multi-user.target