PKGBUILD

# Maintainer: Sébastien Luttringer <seblu@seblu.net>

pkgname=(kernel-install-hook kernel-install-compat kernel-install-grub)
pkgver=2019.03.07
pkgrel=1
arch=('any')
url='https://git.seblu.net/archlinux/kernel-install-poc'
license=('GPL2')
source=('hook.sh'
        'hook.install'
        'hook.remove'
        '50-mkinitcpio-compat.install'
        '90-loaderentry-compat.install'
        '95-grub-update.install')
md5sums=('036439d45eb9384296e46dabec8874fc'
         '8e60d4df3f8386a8972b5a1b25e1b680'
         '44a72eae076d1c208ffee49a07ce7e09'
         '78f5fe7e8881ff261466fb074d1e7c79'
         '1c1b5ad42ad0a6ccae278c57deb92299'
         'cc4481b32207b8f4066971ccdaa20174')

package_kernel-install-hook() {
  pkgdesc='kernel-install hook to run when install/remove kernels'
  depends=('systemd')
  optdepends=('kernel-install-compat: Install kernel in /boot'
              'kernel-install-grub: Regen grub config')

  install -dm755 "$pkgdir"/usr/share/libalpm/hooks
  install -m644 hook.install "$pkgdir"/usr/share/libalpm/hooks/90-kernel-install.hook
  install -m644 hook.remove "$pkgdir"/usr/share/libalpm/hooks/90-kernel-remove.hook
  install -Dm755 hook.sh "$pkgdir"/usr/bin/kernel-install-hook
}

package_kernel-install-compat() {
  pkgdesc='override default kernel-install script to gen arch compatible kernel and initramfs'
  depends=('mkinitcpio' 'kernel-install-hook')

  # disable arch default
  install -dm755 $_f "$pkgdir/etc/kernel/install.d"
  ln -s /dev/null "$pkgdir/etc/kernel/install.d/90-loaderentry.install"
  ln -s /dev/null "$pkgdir/etc/kernel/install.d/50-mkinitcpio.install"
  install -Dm755 50-mkinitcpio-compat.install \
    "$pkgdir/usr/lib/kernel/install.d/50-mkinitcpio-compat.install"
  install -Dm755 90-loaderentry-compat.install \
    "$pkgdir/usr/lib/kernel/install.d/90-loaderentry-compat.install"
}

package_kernel-install-grub() {
  pkgdesc='kernel-install script to regen grub config'
  depends=('grub' 'kernel-install-compat')

  install -Dm755 95-grub-update.install \
    "$pkgdir/usr/lib/kernel/install.d/95-grub-update.install"
}

# vim:set ts=2 sw=2 et: