PKGBUILD

# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>
# Customized version of linux for seblu computers

kernver=3.13
kernsuf=-seblu
kernbld=0

pkgname=linux
pkgver=0
pkgrel=$(($kernbld+1))
arch=('x86_64')
license=('GPL2')
url='http://www.kernel.org'
options=('!strip')
makedepends=('kmod' 'bc' 'git')
source=("git://git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git#tag=v$kernver"
        "config.$CARCH.$kernver")
md5sums=('SKIP' 'SKIP')

shopt -s nullglob

prepare() {
  # apply patches
  cd linux
  for _f in "$srcdir"/*.patch; do
    [[ -r "$_f" ]] || continue
    msg2 "Applying patch: ${_f##*/}"
    patch -N -p1 -i "$_f"
  done

	# loading default config
  # use make localmodconfig to check .config is correct
  msg2 'Copying config'
  install "$srcdir/config.$CARCH.$kernver" .config

	# removing last dot if zero
	#sed -ri 's/^SUBLEVEL = 0$/SUBLEVEL =/' Makefile

	# force suffixe in config (must be the right!)
	msg2 'Setting kernel suffix'
	sed -i "s|CONFIG_LOCALVERSION=.*|CONFIG_LOCALVERSION=\"$kernsuf\"|g" .config

  # remove git informations
  # these info will be used by make kernelrelease and produce wrong information
  # because ownership has fakely be changed by fakeroot during packaging.
  rm -rf .git
}

build() {
  msg2 "Building kernel version: $kernver$kernsuf"

  cd linux

  # define current build version
  echo "$kernbld" > .version

  # Preapre compilation
  msg2 'Preparing compilation'
  yes '' | make config &>/dev/null
  make prepare &>/dev/null

  # Compiling sources
  msg2 'Compiling'
  make bzImage modules
}

package() {
  cd linux
  # get real compiled kernel version
  kernrel=$(make kernelrelease)
  pkgdesc="The Linux Kernel, version $kernrel"
  pkgname="linux-$kernrel"
  pkgver="${kernrel%$kernsuf}"
  pkgver="${pkgver//-/_}"
  provides=("linux=$pkgver" "linux-headers=$pkgver")
  conflicts=("linux-seblu-$pkgver")
  depends=('coreutils' 'linux-firmware' 'kmod' 'mkinitcpio')
  install='install'

  msg2 "Packing kernel version: $kernrel"

  # installing modules
  # disable DEPMOD because it fail due to poor hack in scripts/depmod.sh
  # and it's done by kernel-install in .install
  make INSTALL_MOD_PATH="$pkgdir/usr" DEPMOD=/bin/true modules_install

  # install kernel and map
  install -D -m644 arch/x86/boot/bzImage "$pkgdir/usr/lib/kernel/vmlinuz-$kernrel"

  # remove build and source links
  rm -f "$pkgdir/usr/lib/modules/$kernrel"/{source,build}

  # remove the firmware
  rm -rf "$pkgdir/usr/lib/firmware"

  # copy headers
  copy_headers

  # check rights
  chown -R root.root "$pkgdir/usr/src/linux-$kernrel"
  chmod -R u=rwX,go=rX "$pkgdir/usr/src/linux-$kernrel"

  # gzip -9 all modules to safe 100MB of space
  msg2 'Gzip modules harder'
  find "$pkgdir" -name '*.ko' -exec gzip -9 {} \;
}

copy_headers() {
  # create build symlink into /usr/lib/modules
  ln -sf ../../../src/linux-$kernrel "$pkgdir/usr/lib/modules/$kernrel/build"

  # Copy kernel config files
  cd "$srcdir"/linux
  install -D -m644 Makefile "$pkgdir/usr/src/linux-$kernrel/Makefile"
  install -D -m644 kernel/Makefile "$pkgdir/usr/src/linux-$kernrel/kernel/Makefile"
  install -D -m644 .config "$pkgdir/usr/src/linux-$kernrel/.config"
  for i in localversion*; do
    install -m644 "$i" "$pkgdir/usr/src/linux-$kernrel/$i"
  done

  # create include directory
  install -d "$pkgdir/usr/src/linux-$kernrel/include"

  for i in acpi asm-generic config crypto drm generated linux math-emu \
    media net pcmcia scsi sound trace uapi video xen; do
    cp -a include/$i "$pkgdir/usr/src/linux-$kernrel/include/"
  done

  # copy arch includes for external modules
  install -d "$pkgdir/usr/src/linux-$kernrel/arch/x86"
  cp -a arch/x86/include "$pkgdir/usr/src/linux-$kernrel/arch/x86/"

  # copy files necessary for later builds, like nvidia and vmware
  cp Module.symvers "$pkgdir/usr/src/linux-$kernrel"
  cp -a scripts "$pkgdir/usr/src/linux-$kernrel"

  # fix permissions on scripts dir
  chmod og-w -R "$pkgdir/usr/src/linux-$kernrel/scripts"
  install -d "$pkgdir/usr/src/linux-$kernrel/.tmp_versions"

  install -d "$pkgdir/usr/src/linux-$kernrel/arch/x86/kernel"

  cp arch/x86/Makefile "$pkgdir/usr/src/linux-$kernrel/arch/x86/"
  cp arch/x86/kernel/asm-offsets.s "$pkgdir/usr/src/linux-$kernrel/arch/x86/kernel/"

  # add headers for lirc package
  # pci
  for i in bt8xx cx88 saa7134; do
    install -d "$pkgdir/usr/src/linux-$kernrel/drivers/media/pci/$i"
    cp -a drivers/media/pci/$i/*.h "$pkgdir/usr/src/linux-$kernrel/drivers/media/pci/$i"
  done
  # usb
  for i in cpia2 em28xx pwc sn9c102; do
    install -d "$pkgdir/usr/src/linux-$kernrel/drivers/media/usb/$i"
    cp -a drivers/media/usb/$i/*.h "$pkgdir/usr/src/linux-$kernrel/drivers/media/usb/$i"
  done
  # i2c
  mkdir -p "$pkgdir/usr/src/linux-$kernrel/drivers/media/i2c"
  cp drivers/media/i2c/*.h  "$pkgdir/usr/src/linux-$kernrel/drivers/media/i2c/"
  for i in cx25840; do
    install -d "$pkgdir/usr/src/linux-$kernrel/drivers/media/i2c/$i"
    cp -a drivers/media/i2c/$i/*.h "$pkgdir/usr/src/linux-$kernrel/drivers/media/i2c/$i"
  done

  # add dm headers
  install -d "$pkgdir/usr/src/linux-$kernrel/drivers/md"
  cp drivers/md/*.h  "$pkgdir/usr/src/linux-$kernrel/drivers/md"

  # add inotify.h
  install -d "$pkgdir/usr/src/linux-$kernrel/include/linux"
  cp include/linux/inotify.h "$pkgdir/usr/src/linux-$kernrel/include/linux/"

  # add wireless headers
  install -d "$pkgdir/usr/src/linux-$kernrel/net/mac80211/"
  cp net/mac80211/*.h "$pkgdir/usr/src/linux-$kernrel/net/mac80211/"

  # add dvb headers for external modules
  # in reference to:
  # http://bugs.archlinux.org/task/9912
  install -d "$pkgdir/usr/src/linux-$kernrel/drivers/media/dvb-core"
  cp drivers/media/dvb-core/*.h "$pkgdir/usr/src/linux-$kernrel/drivers/media/dvb-core/"

  # add dvb headers for external modules
  # in reference to:
  # http://bugs.archlinux.org/task/11194
  install -d "$pkgdir/usr/src/linux-$kernrel/include/config/dvb/"
  cp include/config/dvb/*.h "$pkgdir/usr/src/linux-$kernrel/include/config/dvb/"

  # add dvb headers for http://mcentral.de/hg/~mrec/em28xx-new
  # in reference to:
  # http://bugs.archlinux.org/task/13146
  install -d "$pkgdir/usr/src/linux-$kernrel/drivers/media/dvb-frontends/"
  cp drivers/media/dvb-frontends/lgdt330x.h "$pkgdir/usr/src/linux-$kernrel/drivers/media/dvb-frontends/"
  cp drivers/media/i2c/msp3400-driver.h "$pkgdir/usr/src/linux-$kernrel/drivers/media/i2c/"

  # add dvb headers
  # in reference to:
  # http://bugs.archlinux.org/task/20402
  install -d "$pkgdir/usr/src/linux-$kernrel/drivers/media/usb/dvb-usb"
  cp drivers/media/usb/dvb-usb/*.h "$pkgdir/usr/src/linux-$kernrel/drivers/media/usb/dvb-usb/"
  install -d "$pkgdir/usr/src/linux-$kernrel/drivers/media/dvb-frontends"
  cp drivers/media/dvb-frontends/*.h "$pkgdir/usr/src/linux-$kernrel/drivers/media/dvb-frontends/"
  install -d "$pkgdir/usr/src/linux-$kernrel/drivers/media/tuners"
  cp drivers/media/tuners/*.h "$pkgdir/usr/src/linux-$kernrel/drivers/media/tuners/"

  # add xfs and shmem for aufs building
  install -d "$pkgdir/usr/src/linux-$kernrel/fs/xfs"
  install -d "$pkgdir/usr/src/linux-$kernrel/mm"
  cp fs/xfs/xfs_sb.h "$pkgdir/usr/src/linux-$kernrel/fs/xfs/xfs_sb.h"

  # copy in Kconfig files
  for i in $(find . -name "Kconfig*"); do
    install -d "$pkgdir/usr/src/linux-$kernrel"/$(echo $i | sed 's|/Kconfig.*||')
    cp "$i" "$pkgdir/usr/src/linux-$kernrel/$i"
  done

  # strip scripts directory
  find "$pkgdir/usr/src/linux-$kernrel/scripts" -type f -perm -u+w 2>/dev/null | while read binary ; do
    case "$(file -bi "$binary")" in
      *application/x-sharedlib*) # Libraries (.so)
        $_nice strip $STRIP_SHARED "$binary";;
      *application/x-archive*) # Libraries (.a)
        $_nice strip $STRIP_STATIC "$binary";;
      *application/x-executable*) # Binaries
        $_nice strip $STRIP_BINARIES "$binary";;
    esac
  done

  # remove unneeded architectures
  rm -rf "${pkgdir}"/usr/src/"linux-$kernrel"/arch/{alpha,arm,arm26,avr32,blackfin,c6x,cris,frv,h8300,hexagon,ia64,m32r,m68k,m68knommu,mips,microblaze,mn10300,openrisc,parisc,powerpc,ppc,s390,score,sh,sh64,sparc,sparc64,tile,unicore32,um,v850,xtensa}
}

# vim:set ts=2 sw=2 ft=sh et: