PKGBUILD

# Maintainer: Sébastien Luttringer <seblu@seblu.net>
# Customized version of linux for seblu computers

pkgname=linux-seblu
pkgver=5.4.0_rc8
pkgrel=1
pkgdesc='The Linux Kernel cooked by Seblu'
arch=('x86_64')
license=('GPL2')
url='http://www.kernel.org'
options=('!strip' '!buildflags')
makedepends=('glibc' 'libelf' 'kmod' 'git' 'make' 'gcc' 'bc' 'sed' 'cpio')
depends=('linux-firmware' 'kernel-install-hook')
install=linux-seblu.install
source=('git+https://git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git#tag=v5.4-rc8'
        "config.$CARCH")
md5sums=('SKIP'
         '54250a5fcb2ac46698cb59c98150daba')

pkgver() {
  cd linux
  make kernelversion|tr '-' '_'
}

prepare() {
  cd linux

  # apply patches
  for _f in "${source[@]}"; do
    if [[ "$_f" =~ \.patch$ ]]; then
      msg2 "Patching $_f"
      patch -p1 < "$srcdir/$_f"
    fi
  done

  # loading default config
  # use make localmodconfig to check .config is correct
  msg2 'Copying config'
  install "$srcdir/config.$CARCH" .config

  # force suffixe in config (must be the right!)
  msg2 'Setting kernel suffix'
  sed -ri "s|(CONFIG_LOCALVERSION=).*|\1\"${pkgname#linux*}\"|g" .config

  # define current build version
  msg2 'Setting kernel build version'
  echo "$(($pkgrel - 1 ))" > .version

  # no scm version
  # this prevent an issue with “make kernelrelease” which add -dirty to version
  # because ownership of git files has fakely been changed by fakeroot when
  # called from makepkg
  echo '' > .scmversion
}

build() {
  cd linux

  msg2 'Make prepare'
  make prepare

  msg2 'Make bzImage'
  make bzImage

  msg2 'Make modules'
  make modules
}

package() {
  cd linux

  # get real compiled kernel version
  kernrel=$(make kernelrelease)
  pkgdesc+=", version $kernrel"
  pkgname="linux-$kernrel"
  provides=("linux=$pkgver" "linux-headers=$pkgver")

  msg2 "Kernel release: $kernrel"
  msg2 "Package kernel version: $pkgver"

  msg2 'Install vmlinuz'
  install -D -m644 arch/x86/boot/bzImage "$pkgdir/usr/lib/kernel/vmlinuz-$kernrel"

  msg2 'Install modules'
  # disable DEPMOD because it fail due to poor hack in scripts/depmod.sh
  # INSTALL_MOD_STRIP will cause modules to be fully stripped
  make -s INSTALL_MOD_PATH="$pkgdir/usr" INSTALL_MOD_STRIP=1 DEPMOD=/bin/true modules_install

  msg2 'Install sources'
  install_sources

  msg2 'Remove firmwares'
  rm -rf "$pkgdir/usr/lib/firmware"

  msg2 'Generate modules.dep and map files'
  # run depmod to keep track of these files and remove them with the package
  depmod -b "$pkgdir/usr" -F System.map "$kernrel"
}

install_sources() {
  local kernsrc="$pkgdir/usr/src/$pkgname"

  # create $kernsrc directory
  install -d -m 755 "$kernsrc"

  # remove previous build and source links
  rm -f "$pkgdir/usr/lib/modules/$kernrel"/{source,build}
  ln -rs  "$kernsrc" "$pkgdir/usr/lib/modules/$kernrel"/source
  ln -rs  "$kernsrc" "$pkgdir/usr/lib/modules/$kernrel"/build

  # Copy kernel config files
  cd "$srcdir/linux"
  install -D -m644 Makefile "$kernsrc/Makefile"
  install -D -m644 kernel/Makefile "$kernsrc/kernel/Makefile"
  install -D -m644 .config "$kernsrc/.config"
  for i in localversion*; do
    [[ -e "$i" ]] && install -m644 "$i" "$kernsrc/$i"
  done

  # create include directory
  install -d "$kernsrc/include"

  for i in acpi asm-generic config crypto drm generated linux math-emu \
    media net pcmcia scsi sound trace uapi video xen; do
    cp -a include/$i "$kernsrc/include/"
  done

  # copy arch includes for external modules
  install -d "$kernsrc/arch/x86"
  cp -a arch/x86/include "$kernsrc/arch/x86/"

  # copy files necessary for later builds, like nvidia and vmware
  cp Module.symvers "$kernsrc"
  cp -a scripts "$kernsrc"

  # remove broken symlinks of unneeded architectures in scripts
  rm -r "$kernsrc/scripts/dtc/include-prefixes"

  # fix permissions on scripts dir
  chmod og-w -R "$kernsrc/scripts"

  # add x86 makefile
  install -d "$kernsrc/.tmp_versions"
  install -d "$kernsrc/arch/x86/kernel"
  cp arch/x86/Makefile "$kernsrc/arch/x86/"
  cp arch/x86/kernel/asm-offsets.s "$kernsrc/arch/x86/kernel/"

  # add dm headers
  install -d "$kernsrc/drivers/md"
  cp drivers/md/*.h  "$kernsrc/drivers/md"

  # add inotify.h
  install -d "$kernsrc/include/linux"
  cp include/linux/inotify.h "$kernsrc/include/linux/"

  # add wireless headers
  install -d "$kernsrc/net/mac80211/"
  cp net/mac80211/*.h "$kernsrc/net/mac80211/"

  # add dvb headers for external modules
  # in reference to:
  # http://bugs.archlinux.org/task/11194
  install -d "$kernsrc/include/config/dvb/"
  cp include/config/dvb/*.h "$kernsrc/include/config/dvb/"

  # add dvb headers for http://mcentral.de/hg/~mrec/em28xx-new
  # in reference to:
  # http://bugs.archlinux.org/task/13146
  install -Dm644 drivers/media/dvb-frontends/lgdt330x.h \
    "$kernsrc/drivers/media/dvb-frontends/dvb-frontends/lgdt330x.h"
  install -Dm644 drivers/media/i2c/msp3400-driver.h \
    "$kernsrc/drivers/media/i2c/msp3400-driver.h"

  # add dvb headers
  # in reference to:
  # http://bugs.archlinux.org/task/20402
  install -d "$kernsrc/drivers/media/usb/dvb-usb"
  cp drivers/media/usb/dvb-usb/*.h "$kernsrc/drivers/media/usb/dvb-usb/"
  install -d "$kernsrc/drivers/media/dvb-frontends"
  cp drivers/media/dvb-frontends/*.h "$kernsrc/drivers/media/dvb-frontends/"
  install -d "$kernsrc/drivers/media/tuners"
  cp drivers/media/tuners/*.h "$kernsrc/drivers/media/tuners/"

  # copy in Kconfig files
  for i in $(find . -name "Kconfig*"); do
    install -d "$kernsrc"/$(echo $i | sed 's|/Kconfig.*||')
    cp "$i" "$kernsrc/$i"
  done

  # remove unneeded architectures added by copying Kconfig
  for i in "$kernsrc"/arch/*; do
    [[ "${i##*/}" != x86 ]] && rm -rf "$i"
  done

  # add objtool for external module building when enabled VALIDATION_STACK option
  # this is adding dependencty to glibc and libelf to the kernel package
  install -d "$kernsrc/tools/objtool"
  cp tools/objtool/objtool "$kernsrc/tools/objtool"

  # fix permissions
  chown -R root:root "$kernsrc"
  find "$kernsrc" -type d -exec chmod 755 {} \;

  # strip scripts directory
  find "$kernsrc/scripts" -type f -perm -u+w 2>/dev/null | while read binary ; do
    case "$(file -bi "$binary")" in
      *application/x-sharedlib*) # Libraries (.so)
        strip $STRIP_SHARED "$binary";;
      *application/x-archive*) # Libraries (.a)
        strip $STRIP_STATIC "$binary";;
      *application/x-executable*) # Binaries
        strip $STRIP_BINARIES "$binary";;
    esac
  done

  # check rights
  chown -R root.root "$kernsrc"
  chmod -R u=rwX,go=rX "$kernsrc"
}

# vim:set ts=2 sw=2 ft=sh et: